Queries for the ACSCallRecordingIncomingOperations table

For information on using these queries in the Azure portal, see Log Analytics tutorial. For the REST API, see Query.

Returns all distinct combinations of call recording operation and version pairs.

ACSCallRecordingIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Calculates the 90th, 95th, and 99th percentiles of run duration in milliseconds for each call recording operation. It can be customized to be run for a single operation, or for other percentiles.

ACSCallRecordingIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

For every call recording operation, fetch the 5 IP addresses that have called that operation the most.

ACSCallRecordingIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

List every call recording error ordered by recency.

ACSCallRecordingIncomingOperations
| where ResultType == "Failure"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature
| order by TimeGenerated desc
| limit 100

For every call recording operation, count the types of returned results.

ACSCallRecordingIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

Queries Call Recording logs for a particular call connection ID or correlation ID.

ACSCallRecordingIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
//| where CallConnectionId == "<callConnectionId>" // This can be uncommented to filter on a specific call connection ID
| project CorrelationId, CallConnectionId, OperationName, OperationVersion
| limit 100