Note
Access to this page requires authorization. You can try signing in or changing directories.
Access to this page requires authorization. You can try changing directories.
For information on using these queries in the Azure portal, see Log Analytics tutorial. For the REST API, see Query.
Active AI Agents by Owner
Lists active AI agents along with their platform, model, publication status, and owners over the last 7 days.
AgentsInfo
| where LifecycleStatus == "Active"
| where TimeGenerated >= ago(7d)
| summarize arg_max(TimeGenerated, *) by AgentId
| mv-expand Owner = Owners
| project AgentId, Name, Platform, Model, PublishedStatus, Owner, LastUpdatedDateTime
| order by LastUpdatedDateTime desc
AI Agents by Platform and Model
Aggregates the number of AI agents and their lifecycle status grouped by platform and model over the last 30 days.
AgentsInfo
| where TimeGenerated >= ago(30d)
| summarize arg_max(TimeGenerated, *) by AgentId
| summarize AgentCount = dcount(AgentId),
ActiveCount = dcountif(AgentId, LifecycleStatus == "Active"),
BlockedCount = dcountif(AgentId, LifecycleStatus == "Blocked")
by Platform, Model
| order by AgentCount desc