Quickstart: Create an Azure DNS Private Resolver using Terraform

This quickstart describes how to use Terraform to create an Azure DNS Private Resolver. Azure private DNS resolver is a service that provides custom domain name resolution for your private Azure network. It's used to resolve domain names in a virtual network without needing to add a custom DNS solution. The resources created include the Azure DNS Private Resolver, a virtual network, and a subnet. The DNS resolver is associated with the virtual network, and the subnet is configured with a delegation to the DNS Private Resolver service.

Terraform enables the definition, preview, and deployment of cloud infrastructure. Using Terraform, you create configuration files using HCL syntax. The HCL syntax allows you to specify the cloud provider - such as China - and the elements that make up your cloud infrastructure. After you create your configuration files, you create an execution plan that allows you to preview your infrastructure changes before they're deployed. Once you verify the changes, you apply the execution plan to deploy the infrastructure.

The following figure summarizes the general setup used. Subnet address ranges used in templates are slightly different than those shown in the figure.

• If you don't have an Azure account, create an account for trial before you begin.

• Install and configure Terraform.

1. Create a directory in which to test and run the sample Terraform code, and make it the current directory.

2. Create a file named main.tf, and insert the following code:

resource "random_pet" "rg_name" {
  prefix = var.resource_group_name_prefix
}

resource "azurerm_resource_group" "example" {
  location = var.resource_group_location
  name     = random_pet.rg_name.id
}

resource "azurerm_virtual_network" "example" {
  name                = "example-vnet"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
  address_space       = ["10.0.0.0/16"]
}

resource "azurerm_subnet" "example" {
  name                 = "outbounddns"
  resource_group_name  = azurerm_resource_group.example.name
  virtual_network_name = azurerm_virtual_network.example.name
  address_prefixes     = ["10.0.0.64/28"]

  delegation {
    name = "Microsoft.Network.dnsResolvers"
    service_delegation {
      actions = ["Microsoft.Network/virtualNetworks/subnets/join/action"]
      name    = "Microsoft.Network/dnsResolvers"
    }
  }
}

resource "azurerm_private_dns_resolver" "example" {
  name                = "example-resolver"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
  virtual_network_id  = azurerm_virtual_network.example.id
}

1. Create a file named outputs.tf, and insert the following code:

output "resource_group_name" {
  value = azurerm_resource_group.example.name
}

1. Create a file named providers.tf, and insert the following code:

terraform {
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~>3.0"
    }
    random = {
      source  = "hashicorp/random"
      version = "~>3.0"
    }
  }
}

provider "azurerm" {
  features {}
  environment = "china"
}

1. Create a file named variables.tf, and insert the following code:

variable "resource_group_location" {
  type        = string
  default     = "chinanorth3"
  description = "Location of the resource group."
}

variable "resource_group_name_prefix" {
  type        = string
  default     = "rg"
  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
}

Run terraform init to initialize the Terraform deployment. This command downloads the Azure provider required to manage your Azure resources.

terraform init -upgrade

Key points:

• The -upgrade parameter upgrades the necessary provider plugins to the newest version that complies with the configuration's version constraints.

Run terraform plan to create an execution plan.

terraform plan -out main.tfplan

Key points:

• The terraform plan command creates an execution plan, but doesn't execute it. Instead, it determines what actions are necessary to create the configuration specified in your configuration files. This pattern allows you to verify whether the execution plan matches your expectations before making any changes to actual resources.
• The optional -out parameter allows you to specify an output file for the plan. Using the -out parameter ensures that the plan you reviewed is exactly what is applied.

Run terraform apply to apply the execution plan to your cloud infrastructure.

terraform apply main.tfplan

Key points:

• The example terraform apply command assumes you previously ran terraform plan -out main.tfplan.
• If you specified a different filename for the -out parameter, use that same filename in the call to terraform apply.
• If you didn't use the -out parameter, call terraform apply without any parameters.

resource_group_name=$(terraform output -raw resource_group_name)

az network dns record-set list --output table

az network private-dns zone show --name $private_dns_zone_name --resource-group $resource_group_name 

$resource_group_name=$(terraform output -raw resource_group_name)

Get-AzDnsRecordSet -ZoneName $private_dns_zone_name -ResourceGroupName $resource_group_name | Format-Table

Get-AzPrivateDnsZone -Name $private_dns_zone_name -ResourceGroupName $resource_group_name

When you no longer need the resources created via Terraform, do the following steps:

1. Run terraform plan and specify the destroy flag.

terraform plan -destroy -out main.destroy.tfplan

Key points:

• The terraform plan command creates an execution plan, but doesn't execute it. Instead, it determines what actions are necessary to create the configuration specified in your configuration files. This pattern allows you to verify whether the execution plan matches your expectations before making any changes to actual resources.
• The optional -out parameter allows you to specify an output file for the plan. Using the -out parameter ensures that the plan you reviewed is exactly what is applied.

1. Run terraform apply to apply the execution plan.

terraform apply main.destroy.tfplan

Troubleshoot common problems when using Terraform on Azure.