partition operator

适用于：✅Azure 数据资源管理器✅Azure Monitor✅Microsoft Sentinel

partition 运算符根据键列中的值将其输入表的记录分区为多个子表。 该运算符对每个子表运行一个子查询，并生成单个输出表，该表是所有子查询结果的并集。

当需要仅对属于同一分区键的行的子集执行子查询，而不是整个数据集的查询时，分区运算符非常有用。 这些子查询可以包括聚合函数、窗口函数、top N 函数等。

partition 运算符支持多种子查询操作策略：

• Native - 与包含数千个键分区值的隐式数据源一起使用。
• Shuffle - 与包含数百万个键分区值的隐式源一起使用。
• Legacy - 与 64 个或更少键分区值的隐式或显式源一起使用。

Syntax

T|partition [ hint.strategy=策略 ] [ 提示 ] by列(转换SubQuery)

T|partition [ hint.strategy=legacy ] [ 提示 ] byColumn{SubQueryWithSource}

详细了解语法约定。

Parameters

Supported hints

Returns

此运算符返回各个子查询的结果的并集。

Strategies

partition 运算符支持多种子查询操作策略：本机、随机，和旧版。

Native strategy

当分区键的相异值数量不大（以千计）时，应该应用此策略。

子查询必须为表格转换，它不指定表格源。 源是隐式的，将根据子表分区进行分配。 子查询中只能使用某些 受支持的运算符。 分区数量没有限制。

若要使用此策略，请指定 hint.strategy=native。

Shuffle strategy

当分区键的相异值数量很大（以百万计）时，应该应用此策略。

子查询必须为表格转换，它不指定表格源。 源是隐式的，将根据子表分区进行分配。 子查询中只能使用某些 受支持的运算符。 分区数量没有限制。

若要使用此策略，请指定 hint.strategy=shuffle。 有关随机策略和性能的详细信息，请参阅随机执行查询。

本机和随机策略支持的运算符

以下运算符列表可用于具有本机或随机策略的子查询：

• count
• distinct
• extend
• make-series （部分受支持，请参阅注释）
• mv-apply
• mv-expand
• parse
• parse-where
• project
• project-away
• project-keep
• project-rename
• project-reorder
• reduce
• sample
• sample-distinct
• scan
• search
• serialize
• sort
• summarize
• take
• top
• top-hitters
• top-nested
• where

Legacy strategy

出于历史原因，策略 legacy 是默认策略。 但是，我们建议使用 本机 策略或 随机 策略，因为 legacy 方法仅限于 64 个分区，并且效率较低。

在某些情况下，legacy 策略可能是必需的，因为它支持在子查询中包含表格源。 在这种情况下，子查询只能从输入表格源 T 引用键列 Column。若要引用列，请使用语法 toscalar(Column)。

如果子查询是没有表格源的表格转换，则源是隐式的，并且基于子表分区。

若要使用此策略，请指定 hint.strategy=legacy 或省略任何其他策略指示。

Examples

本节中的示例演示如何使用语法帮助你入门。

查找顶部值

在某些情况下，使用 partition 运算符编写查询比使用 top-nested 运算符更高效且更方便。 以下查询针对每个以 summarize 开头的 top 运行计算 State 和 W 的子查询："WYOMING"、"WASHINGTON"、"WEST VIRGINIA" 和 "WISCONSIN"。

StormEvents
| where State startswith 'W'
| partition hint.strategy=native by State 
    (
    summarize Events=count(), Injuries=sum(InjuriesDirect) by EventType, State
    | top 3 by Events 
    ) 

Output

Native strategy

以下查询返回按 EventType 的以“W”开头的每个 TotalInjuries 中的前 2 个 State 值：

StormEvents
| where State startswith 'W'
| partition hint.strategy = native by State
    (
    summarize TotalInjueries = sum(InjuriesDirect) by EventType
    | top 2 by TotalInjueries
    )

Output

Shuffle strategy

以下查询返回前 3 个 DamagedProperty 值 foreach EpisodeId 和列 EpisodeId 和 State。

StormEvents
| partition hint.strategy=shuffle by EpisodeId
    (
    top 3 by DamageProperty
    | project EpisodeId, State, DamageProperty
    )
| count

Output

使用显式源的 Legacy 策略

以下查询运行两个子查询：

• 当 x == 1 时，查询从 StormEvents 返回所有具有 InjuriesIndirect == 1 的行。
• 当 x == 2 时，查询从 StormEvents 返回所有具有 InjuriesIndirect == 2 的行。

最终结果是这两个子查询的并集。

range x from 1 to 2 step 1
| partition hint.strategy=legacy by x {StormEvents | where x == InjuriesIndirect}
| count 

Output

Partition reference

以下示例演示如何使用 as 运算符为每个数据分区指定“名称”，然后在子查询中重复使用该名称。 此方法只与 legacy 策略相关。

T
| partition by Dim
(
    as Partition
    | extend MetricPct = Metric * 100.0 / toscalar(Partition | summarize sum(Metric))
)