ACSAdvancedMessagingOperations 表的查询

项目
11/11/2024

有关在 Azure 门户中使用这些查询的信息，请参阅 Log Analytics 教程。有关 REST API，请参阅查询。

高级消息传递操作

返回高级消息传递操作和版本对的所有不同组合。

ACSAdvancedMessagingOperations
| distinct OperationName, OperationVersion 
| limit 100

高级消息传递操作持续时间百分位数

计算每个聊天操作的第 90、95 和 99 个百分位数（以毫秒为单位）。可以针对单个操作或其他百分位数自定义它。

ACSAdvancedMessagingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

每个操作的高级消息传递前 5 个 IP 地址

对于每个高级消息传递操作，提取调用该操作最多的 5 个 IP 地址。

ACSAdvancedMessagingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

高级消息传递操作错误

列出按近期性排序的每个高级消息传递错误。

ACSAdvancedMessagingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100

高级消息传递操作结果计数

对于每个高级消息传递操作，计数返回结果的类型。

ACSAdvancedMessagingOperations
| summarize Count = count() by OperationName, OperationVersion, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

高级消息传递通道活动

过去 24 小时内每个通道的消息活动摘要。

ACSAdvancedMessagingOperations
| where TimeGenerated > ago(24h)
| summarize count() by ChannelId, MessageType
| order by ChannelId asc

高级消息传递消息状态计数

过去 24 小时内的消息状态计数。

ACSAdvancedMessagingOperations
| where TimeGenerated > ago(24h)
| summarize Count = count() by MessageType, MessageStatus
| order by MessageType asc, Count desc

通过