通过

AEWComputePipelinesLogs 表的查询

  • 项目

有关在 Azure 门户中使用这些查询的信息，请参阅 Log Analytics 教程。 有关 REST API，请参阅查询。

AEWComputePipelinesLogs 获取每日任务计数

从所选时间范围内的计算管道记录中获取每日任务计数。

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestSucceeded" or EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| summarize Count = count() by Date = bin(TimeGenerated, 1d), ExperimentationGroup = tostring(Properties.ExperimentationGroup)
| sort by Date

AEWComputePipelinesLogs 获取失败的任务详细信息

从所选时间范围内的计算管道记录中获取最新的 100 个失败任务的详细信息。

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| project
    TimeGenerated
    ,EventName
    ,ExperimentationGroup = Properties.ExperimentationGroup
    ,AnalysisType = Properties.AnalysisType
| sort by TimeGenerated desc
| take 100

AEWComputePipelinesLogs 获取长期作业

从过去七天的计算管道记录中获取长期作业。

AEWComputePipelinesLogs
| where EventName =~ "CosmosJobUtilization"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| where todouble(Properties.JobRunningInSeconds) >= 24 * 60 * 60
| project
    TimeGenerated
    ,EventName
    ,ExperimentationGroup = Properties.ExperimentationGroup
    ,AnalysisType = Properties.AnalysisType
| sort by TimeGenerated desc

AEWComputePipelinesLogs 获取任务 E2E 延迟时间

获取所选时间范围内计算管道记录的任务 E2E 延迟时间。

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestSucceeded" or EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| summarize
  ScorecardRequestTimeInHoursP99 = percentile(todouble(Properties.ScorecardProcessingInSeconds) / 60 / 60, 99)
  ,ScorecardRequestTimeInHoursAvg = avg(todouble(Properties.ScorecardProcessingInSeconds) / 60 / 60)
  by Date = bin(TimeGenerated, 1d), ExperimentationGroup = tostring(Properties.ExperimentationGroup)
| sort by Date, ExperimentationGroup