LAQueryLogs 表的查询

项目
11/11/2024

有关在 Azure 门户中使用这些查询的信息，请参阅 Log Analytics 教程。有关 REST API，请参阅查询。

请求最多的 ResourceId

过去 24 小时内查询最多的资源。

LAQueryLogs
| extend reqContext = parse_json(RequestContext)
| extend datasources = array_concat(reqContext["resources"], reqContext["workspaces"], reqContext["applications"])
| mv-expand datasources
| summarize reqCount = count() by tostring(datasources)
| order by reqCount desc

未授权用户

获取过去 24 小时内的未授权用户及其请求计数的列表。

LAQueryLogs
| where ResponseCode == "403"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

受限用户

获取过去 24 小时内的受限用户及其请求计数的列表。

LAQueryLogs
| where ResponseCode == "429"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

请求计数(按 ResponseCode)

过去 1 小时内 1 分钟内按响应代码统计的请求数。

LAQueryLogs
| where TimeGenerated > ago(1h)
| summarize count() by tostring(ResponseCode), bin(TimeGenerated, 1m)
| render columnchart with (kind=stacked)

前 10 个资源密集型查询

过去 24 小时内的前 10 个资源密集型查询（基于 CPU 使用率）。

LAQueryLogs
| top 10 by StatsCPUTimeMs desc nulls last

时间范围最长的前 10 个查询

获取过去 24 小时内扫描时间范围最长的前 10 个查询。

LAQueryLogs
| extend DataProcessedTimeRange = format_timespan(StatsDataProcessedEnd - StatsDataProcessedStart, 'dd.hh:mm:ss:FF')
| top 10 by DataProcessedTimeRange desc nulls last

通过