快速入门：使用 Terraform 创建 Azure 容器注册表

在本快速入门中，你将使用 Terraform 创建 Azure 容器注册表和资源组。 Azure 容器注册表是托管的 Docker 注册表服务，用于存储专用的 Docker 容器映像。 它通常与 Azure Kubernetes 服务 (AKS)、Azure 应用服务和其他 Azure 服务一起使用，以拉取容器映像。 注册表存储在资源组中，资源组是部署在 Azure 上的资源的逻辑容器。 这些资源通过将前缀与随机字符串组合在一起，以唯一的名称创建，确保它们在你的 Azure 订阅中是唯一的。

使用 Terraform 可以定义、预览和部署云基础结构。 使用 Terraform 时，请使用 HCL 语法来创建配置文件。 利用 HCL 语法，可指定 Azure 这样的云提供程序和构成云基础结构的元素。 创建配置文件后，请创建一个执行计划，利用该计划，可在部署基础结构更改之前先预览这些更改。 验证了更改后，请应用该执行计划以部署基础结构。

先决条件

• 创建具有活动订阅的 Azure 帐户。 可以创建一个试用订阅。

• 安装和配置 Terraform。

实现 Terraform 代码

1. 创建用于测试和运行示例 Terraform 代码的目录，并将其设为当前目录。

2. 创建名为 main.tf 的文件并插入以下代码：

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   resource "random_string" "acr_name" {
     length  = 5
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_container_registry" "example" {
     name                = "${random_string.acr_name.result}registry"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     sku                 = "Standard"
   }
   

3. 创建名为 outputs.tf 的文件并插入以下代码：

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "container_registry_name" {
     value = azurerm_container_registry.example.name
   }
   
   output "container_registry_login_server" {
     value = azurerm_container_registry.example.login_server
   }
   

4. 创建名为 providers.tf 的文件并插入以下代码：

   terraform {
     required_version = ">=1.0"
   
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

5. 创建名为 variables.tf 的文件并插入以下代码：

   variable "resource_group_location" {
     type        = string
     default     = "chinaeast2"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   

初始化 Terraform

运行 terraform init，将 Terraform 部署进行初始化。 此命令将下载管理 Azure 资源所需的 Azure 提供程序。

terraform init -upgrade

要点：

• 参数 -upgrade 可将必要的提供程序插件升级到符合配置版本约束的最新版本。

创建 Terraform 执行计划

运行 terraform plan 以创建执行计划。

terraform plan -out main.tfplan

要点：

• terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
• 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

应用 Terraform 执行计划

运行 terraform apply，将执行计划应用到云基础结构。

terraform apply main.tfplan

要点：

• 示例 terraform apply 命令假设你先前运行了 terraform plan -out main.tfplan。
• 如果为 -out 参数指定了不同的文件名，请在对 terraform apply 的调用中使用该相同文件名。
• 如果未使用 -out 参数，请调用不带任何参数的 terraform apply。

验证结果

az acr show --name <registry_name> --resource-group <resource_group_name>

清理资源

不再需要通过 Terraform 创建的资源时，请执行以下步骤：

1. 运行 terraform plan 并指定 destroy 标志。

   terraform plan -destroy -out main.destroy.tfplan
   

   要点：

   • terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
   • 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

2. 运行 terraform apply 以应用执行计划。

   terraform apply main.destroy.tfplan
   

Azure 上的 Terraform 故障排除

排查在 Azure 上使用 Terraform 时遇到的常见问题。

后续步骤