通过

bin_at()

  • 项目

适用于：✅Azure 数据资源管理器✅Azure Monitor✅Microsoft Sentinel

返回向下舍入到与固定参考点对齐的最接近箱大小的值。

与预定义了对齐点的 bin() 函数不同，bin_at() 允许定义一个固定点进行对齐。 结果可以在固定点之前或之后对齐。

语法

bin_at (value,bin_size,fixed_point)

详细了解语法约定。

参数

客户 类型​​ 必需 Description
value int、long、real、timespan 或 datetime ✔️ 要舍入的值。
bin_size int、long、real 或 timespan ✔️ 每个箱的大小。
fixed_point int、long、real、timespan 或 datetime ✔️ 与 value 的类型相同的常量，用作固定参考点。

注意

如果 value 是 timespan 或 datetime，则 bin_size 必须是 timespan。

返回

低于给定的 value 且与指定 fixed_point 对齐的最接近 bin_size 倍数。

示例

在以下示例中，value 向下舍入到与 fixed_point 对齐的最接近 bin_size。

print bin_at(6.5, 2.5, 7)

输出

print_0
4.5

在以下示例中，时间间隔被装入与 12 小时固定点对齐的每日箱中。 返回值为 -12，因为与 12 小时对齐的每日箱向下舍入到前一天的 12 时。

print bin_at(time(1h), 1d, 12h)

输出

print_0
-12:00:00

在以下示例中，每日箱与中午对齐。

print bin_at(datetime(2017-05-15 10:20:00.0), 1d, datetime(1970-01-01 12:00:00.0))

输出

print_0
2017-05-14T12:00:00Z

在以下示例中，bin 为每周，与 2017 年 6 月 6 日星期日的开始对齐。 该示例返回一个与星期日对齐的箱。

print bin_at(datetime(2017-05-17 10:20:00.0), 7d, datetime(2017-06-04 00:00:00.0))

输出

print_0
2017-05-14T00:00:00Z

在以下示例中，事件总数分组到与 fixed_point 日期和时间对齐的每日箱中。 fixed_point 值包含在其中一个返回的箱中。

datatable(Date:datetime, NumOfEvents:int)[
datetime(2018-02-24T15:14),3,
datetime(2018-02-24T15:24),4,
datetime(2018-02-23T16:14),4,
datetime(2018-02-23T17:29),4,
datetime(2018-02-26T15:14),5]
| summarize TotalEvents=sum(NumOfEvents) by bin_at(Date, 1d, datetime(2018-02-24 15:14:00.0000000))

输出

日期 TotalEvents
2018-02-23T15:14:00Z 8
2018-02-24T15:14:00Z 7
2018-02-26T15:14:00Z 5

相关内容