inline_external_table 运算符

使用 “版本 ”下拉列表切换服务。 了解有关导航的详细信息。
适用于： ✅ Azure 数据资源管理器

运算符inline_external_table返回一个表，该表的架构在查询本身中定义或从 Delta Lake 元数据推断，以及从外部存储项目（例如Azure Blob 存储中的 blob 或Azure Data Lake Storage中的文件）读取其数据。

Syntax

存储模式

inline_external_table ( columnName:columnType [, ...] )kind=storage [partitionby(partitionName:partitionType [=表达式] [, ...])][pathformat=(pathFormatElement •)] dataformat=dataFormat(storageConnectionString [, ...] ) [with(propertyName=propertyValue [, ...])]

增量模式

inline_external_table [(columnName:columnType [, ...] )] kind=delta(storageConnectionString)

详细了解语法约定。

Parameters

declare query_parameters(URI:string);
inline_external_table(x:string) kind=storage dataformat=txt (URI)

支持的属性

以下属性仅适用于 kind=storage.

Returns

该inline_external_table运算符返回一个数据表，该表的数据是从指定的存储项目检索的，由存储连接字符串指示。

在 ， kind=storage表架构是在查询中指定的架构。 在查询 kind=delta中指定表架构，或从 Delta 日志推断。 从 Delta 元数据推断的分区列将作为虚拟列返回。

示例

以下示例查询存储在外部存储中的 Parquet 文件。

inline_external_table(Timestamp:datetime, DeviceId:string, Value:real)
    kind=storage
    dataformat=parquet
    (h@"https://mycompanystorage.blob.core.chinacloudapi.cn/iot/2026/06/01/data.parquet?...SAS...")
| summarize AvgValue = avg(Value) by DeviceId

输出

以下示例查询存储在外部存储中的多个 CSV 文件。

inline_external_table(Timestamp:datetime, ProductId:string, Quantity:long)
    kind=storage
    dataformat=csv
    (
        h@"https://mycompanystorage.blob.core.chinacloudapi.cn/archivedproducts/2026/06/01/part-00000.csv.gz?...SAS...",
        h@"https://mycompanystorage.blob.core.chinacloudapi.cn/archivedproducts/2026/06/02/part-00000.csv.gz?...SAS..."
    )
    with(includeHeaders='All')
| summarize TotalQuantity = sum(Quantity) by ProductId

输出

以下示例查询存储在外部存储中的已分区 Parquet 文件。

inline_external_table(Timestamp:datetime, DeviceId:string, Region:string, Value:real)
    kind=storage
    partition by(
        Day:datetime = startofday(Timestamp),
        RegionPartition:string = Region
    )
    pathformat=('day=' datetime_pattern('yyyy/MM/dd', Day) '/region=' RegionPartition)
    dataformat=parquet
    (h@"https://mycompanystorage.blob.core.chinacloudapi.cn/iotpartitioned;managed_identity=...")
| where Day between (datetime(2026-01-01) .. datetime(2026-01-07))
| summarize AvgValue = avg(Value) by Region

输出

以下示例查询 Delta Lake 表根目录。 架构是从 Delta 日志推断的，推断 Amount 列用于筛选。

inline_external_table
    kind=delta
    (h@"abfss://filesystem@storageaccount.dfs.core.chinacloudapi.cn/delta/customer-events;sharedkey=...")
| where Amount > 0
| take 10

输出

以下示例使用显式架构查询 Delta Lake 表根目录。

inline_external_table(Timestamp:datetime, CustomerId:string, Amount:real)
    kind=delta
    (h@"abfss://filesystem@storageaccount.dfs.core.chinacloudapi.cn/delta/customer-events;sharedkey=...")
| summarize TotalAmount = sum(Amount) by CustomerId

输出

相关内容

• 有关存储连接字符串的详细信息，请参阅 存储连接字符串。
• 有关外部表的详细信息，请参阅 外部表。