快速入门：使用 Bicep 创建和配置 Azure DDoS 网络保护

此快速入门介绍如何使用 Bicep 创建分布式拒绝服务 (DDoS) 防护计划和虚拟网络，然后为虚拟网络启用防护计划。 Azure DDoS 防护计划定义了一组跨订阅启用 DDoS 网络防护的虚拟网络。 可以为组织配置一个 DDoS 防护计划，然后从多个订阅将虚拟网络链接到相同计划。

Bicep 是一种特定于域的语言 (DSL)，使用声明性语法来部署 Azure 资源。 它提供简明的语法、可靠的类型安全性以及对代码重用的支持。 Bicep 会针对你的 Azure 基础结构即代码解决方案提供最佳创作体验。

先决条件

如果没有 Azure 订阅，请在开始前创建一个试用版订阅。

查看 Bicep 文件

本快速入门中使用的 Bicep 文件来自 Azure 快速入门模板。

@description('Specify a DDoS protection plan name.')
param ddosProtectionPlanName string

@description('Specify a DDoS virtual network name.')
param virtualNetworkName string

@description('Specify a location for the resources.')
param location string = resourceGroup().location

@description('Specify the virtual network address prefix')
param vnetAddressPrefix string = '172.17.0.0/16'

@description('Specify the virtual network subnet prefix')
param subnetPrefix string = '172.17.0.0/24'

@description('Enable DDoS protection plan.')
param ddosProtectionPlanEnabled bool = true

resource ddosProtectionPlan 'Microsoft.Network/ddosProtectionPlans@2021-05-01' = {
  name: ddosProtectionPlanName
  location: location
}

resource virtualNetwork 'Microsoft.Network/virtualNetworks@2021-05-01' = {
  name: virtualNetworkName
  location: location
  properties: {
    addressSpace: {
      addressPrefixes: [
        vnetAddressPrefix
      ]
    }
    subnets: [
      {
        name: 'default'
        properties: {
          addressPrefix: subnetPrefix
        }
      }
    ]
    enableDdosProtection: ddosProtectionPlanEnabled
    ddosProtectionPlan: {
      id: ddosProtectionPlan.id
    }
  }
}

Bicep 文件定义两个资源：

• Microsoft.Network/ddosProtectionPlans
• Microsoft.Network/virtualNetworks

部署 Bicep 文件

在本示例中，Bicep 文件会新建资源组、DDoS 防护计划和虚拟网络。

1. 请将 Bicep 文件保存到您的本地计算机，并命名为 main.bicep。

2. 使用 Azure CLI 或 Azure PowerShell 来部署该 Bicep 文件。

   • CLI
   • PowerShell

   az group create --name exampleRG --location chinaeast
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters ddosProtectionPlanName=<plan-name> virtualNetworkName=<network-name>
   

   注意

   将 <plan-name> 替换为某个 DDoS 防护计划的名称。 将 <network-name> 替换为 DDoS 虚拟网络名称。

   部署完成后，应会看到一条指出部署成功的消息。

查看已部署的资源

使用 Azure 门户、Azure CLI 或 Azure PowerShell 列出资源组中已部署的资源。

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

清理资源

如果不再需要资源组及其资源，请使用 Azure 门户、Azure CLI 或 Azure PowerShell 将其删除。

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

后续步骤

要了解如何查看和配置 DDoS 防护计划的遥测，请继续阅读教程。