快速入门：使用 Bicep 在多租户 Azure 逻辑应用中创建和部署消耗逻辑应用工作流

适用于：Azure 逻辑应用（消耗）

Azure 逻辑应用是一种云服务，可帮助你通过从数百个连接器中进行选择来创建和运行自动化工作流，用于集成数据、应用、基于云的服务和本地系统。 本快速入门重点介绍部署 Bicep 文件创建基本消耗逻辑应用逻辑的过程，该工作流用于按小时检查 Azure 的状态，并且在多租户 Azure 逻辑应用上运行。

Bicep 是一种特定于域的语言 (DSL)，使用声明性语法来部署 Azure 资源。 它提供简明的语法、可靠的类型安全性以及对代码重用的支持。 Bicep 会针对你的 Azure 基础结构即代码解决方案提供最佳创作体验。

先决条件

如果没有 Azure 订阅，可以在开始前注册一个试用版 Azure 订阅。

查阅 Bicep 文件

本快速入门中使用的 Bicep 文件来自 Azure 快速入门模板。

快速入门模板会创建一个消耗逻辑应用工作流，该工作流使用定期触发器和 HTTP 内置操作，前者设置为每小时运行一次，后者则调用返回 Azure 状态的 URL。 内置操作在 Azure 逻辑应用平台上以本机方式运行。

此 Bicep 文件创建以下 Azure 资源：

• Microsoft.Logic/workflows，它会为逻辑应用创建工作流。

  @description('The name of the logic app to create.')
  param logicAppName string
  
  @description('A test URI')
  param testUri string = 'https://status.azure.com/en-us/status/'
  
  @description('Location for all resources.')
  param location string = resourceGroup().location
  
  var frequency = 'Hour'
  var interval = '1'
  var type = 'recurrence'
  var actionType = 'http'
  var method = 'GET'
  var workflowSchema = 'https://schema.management.azure.com/providers/Microsoft.Logic/schemas/2016-06-01/workflowdefinition.json#'
  
  resource stg 'Microsoft.Logic/workflows@2019-05-01' = {
     name: logicAppName
     location: location
     tags: {
       displayName: logicAppName
     }
     properties: {
       definition: {
         '$schema': workflowSchema
         contentVersion: '1.0.0.0'
         parameters: {
           testUri: {
             type: 'string'
             defaultValue: testUri
           }
         }
         triggers: {
           recurrence: {
             type: type
             recurrence: {
               frequency: frequency
               interval: interval
             }
           }
         }
         actions: {
           actionType: {
             type: actionType
             inputs: {
               method: method
               uri: testUri
             }
           }
         }
       }
     }
  }
  

部署 Bicep 文件

1. 将该 Bicep 文件另存为本地计算机上的 main.bicep。

2. 使用 Azure CLI 或 Azure PowerShell 来部署该 Bicep 文件。

   • CLI
   • PowerShell

   az group create --name exampleRG --location chinaeast
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters logicAppName=<logic-name>
   

部署完成后，应会看到一条指出部署成功的消息。

查看已部署的资源

使用 Azure 门户、Azure CLI 或 Azure PowerShell 列出资源组中已部署的资源。

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

清理资源

如果不再需要逻辑应用，请使用 Microsoft Azure 门户、Azure CLI 或 Azure PowerShell 将资源组及其资源删除。

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

后续步骤