此页面是针对 Azure 网络的 Azure Resource Graph 示例查询的集合。
示例查询
对具有由订阅配置的 IP 地址的资源进行计数
使用“列出所有公共 IP 地址”示例查询，并添加summarizecount()，我们可以按订阅获取配置有 IP 地址的资源列表。
Resources
| where type contains 'publicIPAddresses' and isnotempty(properties.ipAddress)
| summarize count () by subscriptionId
az graph query -q "Resources | where type contains 'publicIPAddresses' and isnotempty(properties.ipAddress) | summarize count () by subscriptionId"
获取网络接口的虚拟网络和子网
使用正则表达式 parse 从资源 ID 属性中获取虚拟网络和子网名称。 虽然 parse 支持从复杂字段获取数据，但如果属性存在，则最好直接访问属性，而不是使用 parse。
Resources
| where type =~ 'microsoft.network/networkinterfaces'
| project id, ipConfigurations = properties.ipConfigurations
| mvexpand ipConfigurations
| project id, subnetId = tostring(ipConfigurations.properties.subnet.id)
| parse kind=regex subnetId with '/virtualNetworks/' virtualNetwork '/subnets/' subnet
| project id, virtualNetwork, subnet
az graph query -q "Resources | where type =~ 'microsoft.network/networkinterfaces' | project id, ipConfigurations = properties.ipConfigurations | mvexpand ipConfigurations | project id, subnetId = tostring(ipConfigurations.properties.subnet.id) | parse kind=regex subnetId with '/virtualNetworks/' virtualNetwork '/subnets/' subnet | project id, virtualNetwork, subnet"
列出所有公共 IP 地址
类似于“显示包含存储的资源”查询，查找包含单词 publicIPAddresses的类型的所有内容。 此查询扩展了该模式，条件是仅包含properties.ipAddressisnotempty的结果，仅返回properties.ipAddress，并筛选出前 100 名的结果。 可能需要根据所选 shell 对引号进行转义。
Resources
| where type contains 'publicIPAddresses' and isnotempty(properties.ipAddress)
| project properties.ipAddress
| limit 100
az graph query -q "Resources | where type contains 'publicIPAddresses' and isnotempty(properties.ipAddress) | project properties.ipAddress | limit 100"
显示未关联的网络安全组
此查询返回未与网络接口或子网关联的网络安全组 (NSG)。
Resources
| where type =~ 'microsoft.network/networksecuritygroups' and isnull(properties.networkInterfaces) and isnull(properties.subnets)
| project name, resourceGroup
| sort by name asc
az graph query -q "Resources | where type =~ 'microsoft.network/networksecuritygroups' and isnull(properties.networkInterfaces) and isnull(properties.subnets) | project name, resourceGroup | sort by name asc"