快速入门：使用 Terraform 创建 Azure Analysis Services 服务器

本文介绍了如何使用 Terraform 创建 Azure Analysis Services 服务器。

在本文中，学习如何：

• 安装和配置 Terraform

  注意

  应事先配置环境参数才能访问由世纪互联运营的 Azure。

  1. Azure CLI： export ARM_ENVIRONMENT=china
  2. PowerShell：$env:ARM_ENVIRONMENT = "china"

1. 创建用于测试和运行示例 Terraform 代码的目录，并将其设为当前目录。

2. 创建名为 main.tf 的文件并插入下列代码：

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_analysis_services_server_name" {
     length  = 25
     upper   = false
     numeric = false
     special = false
   }
   
   resource "azurerm_analysis_services_server" "server" {
     name                      = random_string.azurerm_analysis_services_server_name.result
     resource_group_name       = azurerm_resource_group.rg.name
     location                  = azurerm_resource_group.rg.location
     sku                       = var.sku
     backup_blob_container_uri = var.backup_blob_container_uri
   
     ipv4_firewall_rule {
       name        = "AllowFromAll"
       range_start = "0.0.0.0"
       range_end   = "255.255.255.255"
     }
   }
   
   

3. 创建名为 outputs.tf 的文件并插入下列代码：

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "analysis_services_server_name" {
     value = azurerm_analysis_services_server.server.name
   }
   
   

4. 创建名为 providers.tf 的文件并插入下列代码：

   terraform {
     required_version = ">=0.12"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. 创建名为 variables.tf 的文件并插入下列代码：

   variable "resource_group_location" {
     type        = string
     default     = "chinanorth"
     description = "Location for all resources."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "sku" {
     type        = string
     description = "The sku name of the Azure Analysis Services server to create. Choose from: B1, B2, S0, S1, S2, S4, S8v2, S9v2. Some skus are region specific. See https://docs.azure.cn/analysis-services/analysis-services-overview#availability-by-region"
     default     = "S0"
   }
   
   variable "backup_blob_container_uri" {
     type        = string
     description = "The SAS URI to a private Azure Blob Storage container with read, write and list permissions. Required only if you intend to use the backup/restore functionality. See https://learn.microsoft.com/analysis-services/analysis-services-backup"
     default     = null
   }
   
   

运行 terraform init，将 Terraform 部署进行初始化。 此命令将下载管理 Azure 资源所需的 Azure 提供程序。

terraform init -upgrade

要点：

• 参数 -upgrade 可将必要的提供程序插件升级到符合配置版本约束的最新版本。

运行 terraform plan 以创建执行计划。

terraform plan -out main.tfplan

要点：

• terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
• 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

运行 terraform apply，将执行计划应用到云基础结构。

terraform apply main.tfplan

要点：

• 示例 terraform apply 命令假设你先前运行了 terraform plan -out main.tfplan。
• 如果为 -out 参数指定了不同的文件名，请在对 terraform apply 的调用中使用该相同文件名。
• 如果未使用 -out 参数，请调用不带任何参数的 terraform apply。

1. 打开 PowerShell 命令提示符。

2. 获取 Azure 资源组名称。

   $resource_group_name=$(terraform output -raw resource_group_name)
   

3. 获取服务器名称。

   $analysis_services_server_name=$(terraform output -raw analysis_services_server_name)
   

4. 运行 Get-AzAnalysisServicesServer 以显示有关新服务器的信息。

   Get-AzAnalysisServicesServer -ResourceGroupName $resource_group_name `
                                -Name $analysis_services_server_name
   

不再需要通过 Terraform 创建的资源时，请执行以下步骤：

1. 运行 terraform plan 并指定 destroy 标志。

   terraform plan -destroy -out main.destroy.tfplan
   

   要点：

   • terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
   • 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

2. 运行 terraform apply 以应用执行计划。

   terraform apply main.destroy.tfplan
   

排查在 Azure 上使用 Terraform 时遇到的常见问题