迁移到 Azure Kubernetes 服务 (AKS)

以下示例使用虚拟机规模集支持的单个节点池创建 AKS 群集。 它会在群集的节点池中启用群集自动缩放程序，并将最小节点数设置为 1，将最大节点数设置为 3。

1. 使用 az group create 命令创建资源组。

   az group create --name myResourceGroup --location eastus
   

2. 使用 az aks create 命令创建 AKS 群集。

   az aks create \
       --resource-group myResourceGroup \
       --name myAKSCluster \
       --node-count 1 \
       --vm-set-type VirtualMachineScaleSets \
       --load-balancer-sku standard \
       --enable-cluster-autoscaler \
       --min-count 1 \
       --max-count 3 \
       --generate-ssh-keys
   

以下代码在 Azure 中创建资源组和 Kubernetes 群集，并使用 Terraform 自动缩放和特定的网络设置。

1. 创建用于测试和运行示例 Terraform 代码的目录，并将其设为当前目录。

2. 创建名为 main.tf 的文件并插入以下代码：

resource "random_pet" "rg_name" {
  prefix = var.resource_group_name_prefix
}

resource "azurerm_resource_group" "rg" {
  location = var.resource_group_location
  name     = random_pet.rg_name.id
}

resource "random_string" "aks_cluster_name" {
  length  = 12
  special = false
}

resource "azurerm_kubernetes_cluster" "aks_cluster" {
  name                = random_string.aks_cluster_name.result
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  dns_prefix          = "myakscluster"

  default_node_pool {
    type                = "VirtualMachineScaleSets"
    name                = "default"
    node_count          = 1
    max_count           = 3
    min_count           = 1
    vm_size             = "Standard_DS2_v2"
    enable_auto_scaling = true
    upgrade_settings {
      drain_timeout_in_minutes      = 90
      max_surge                     = "10%"
      node_soak_duration_in_minutes = 0
    }
  }

  network_profile {
    network_plugin    = "azure"
    load_balancer_sku = "standard"
  }

  identity {
    type = "SystemAssigned"
  }

  tags = {
    Environment = "Production"
  }
}

1. 创建名为 outputs.tf 的文件并插入以下代码：

output "resource_group_name" {
  value = azurerm_resource_group.rg.name
}

output "aks_cluster_name" {
  value = azurerm_kubernetes_cluster.aks_cluster.name
}

1. 创建名为 providers.tf 的文件并插入以下代码：

terraform {
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~>3.0"
    }
    random = {
      source  = "hashicorp/random"
      version = "~>3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

1. 创建名为 variables.tf 的文件并插入以下代码：

variable "resource_group_location" {
  type        = string
  default     = "eastus"
  description = "Location of the resource group."
}

variable "resource_group_name_prefix" {
  type        = string
  default     = "rg"
  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
}

1. 初始化 Terraform。

   运行 terraform init，将 Terraform 部署进行初始化。 此命令将下载管理 Azure 资源所需的 Azure 提供程序。

   terraform init -upgrade
   

   要点：

   • 参数 -upgrade 可将必要的提供程序插件升级到符合配置版本约束的最新版本。

2. 创建 Terraform 执行计划。

   运行 terraform plan 以创建执行计划。

   terraform plan -out main.tfplan
   

   要点：

   • terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
   • 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

3. 应用 Terraform 执行计划。

   运行 terraform apply，将执行计划应用到云基础结构。

   terraform apply main.tfplan
   

   要点：

   • 示例 terraform apply 命令假设你先前运行了 terraform plan -out main.tfplan。
   • 如果为 -out 参数指定了不同的文件名，请在对 terraform apply 的调用中使用该相同文件名。
   • 如果未使用 -out 参数，请调用不带任何参数的 terraform apply。