快速入门：使用 Bicep 创建应用服务应用

本快速入门使用以下模板。 它在 Linux 上部署应用服务计划和应用服务应用。 它还从 Azure 示例存储库部署示例 Node.js Hello World 应用程序。

param webAppName string = uniqueString(resourceGroup().id) // Generate a unique string for the web app name
param sku string = 'F1' // Tier of the App Service plan
param linuxFxVersion string = 'node|20-lts' // Runtime stack of the web app
param location string = resourceGroup().location // Location for all resources
param repositoryUrl string = 'https://github.com/Azure-Samples/nodejs-docs-hello-world'
param branch string = 'main'
var appServicePlanName = toLower('AppServicePlan-${webAppName}')
var webSiteName = toLower('wapp-${webAppName}')

resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  properties: {
    reserved: true
  }
  sku: {
    name: sku
  }
  kind: 'linux'
}

resource appService 'Microsoft.Web/sites@2023-12-01' = {
  name: webSiteName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    siteConfig: {
      linuxFxVersion: linuxFxVersion
    }
  }
}

resource srcControls 'Microsoft.Web/sites/sourcecontrols@2023-12-01' = {
  parent: appService
  name: 'web'
  properties: {
    repoUrl: repositoryUrl
    branch: branch
    isManualIntegration: true
  }
}

该模板定义了三个 Azure 资源：

• Microsoft.Web/serverfarms：创建应用服务计划。
• Microsoft.Web/sites：创建应用服务应用。
• Microsoft.Web/sites/sourcecontrols：创建外部 Git 部署配置。

该模板包含以下为方便起见预定义的参数：

部署模板

将模板复制并粘贴到您首选的编辑器或 IDE 中的空白文件中。 然后将该文件保存到本地工作目录。 使用 .bicep 文件扩展名。

在这里，使用 Azure CLI 部署模板。 还可以使用 Azure 门户、Azure PowerShell 或 REST API。 若要了解其他部署方法，请参阅 使用 Azure CLI 部署 Bicep 文件。

以下代码将创建一个资源组、一个应用服务计划和一个 Web 应用。 系统会为你设置默认资源组、应用服务计划和位置。 将 <app-name> 替换为一个全局唯一的应用名称。 有效字符是 a-z， 0-9和连字符（-）。

打开安装 Azure CLI 的终端。 运行此代码在 Linux 上创建 Node.js 应用：

az group create --name myResourceGroup --location "chinaeast" &&
az deployment group create --resource-group myResourceGroup --template-file <path-to-template>

若要部署其他语言堆栈，请使用相应的值更新 linuxFxVersion。 下表列出了示例。 若要显示当前版本，请在 Cloud Shell 中运行以下命令： az webapp config show --resource-group myResourceGroup --name <app-name> --query linuxFxVersion

本快速入门使用以下模板。 它在 Windows 上部署应用服务计划和应用服务应用。 它还从 Azure 示例存储库部署示例 .NET Hello World 应用。

param webAppName string = uniqueString(resourceGroup().id) // Generate a unique name for the web app
param location string = resourceGroup().location // Location for all resources
param sku string = 'P1V3' // Tier of the App Service plan
param dockerContainerImage string = 'mcr.microsoft.com/dotnet/framework/samples:aspnetapp' // Sample .NET app
var appServicePlanName = toLower('ASP-${webAppName}') // Generate a unique name for the App Service plan

resource appServicePlan 'Microsoft.Web/serverfarms@2021-02-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: sku
  }
  properties: {
    hyperV: true
  }
}

resource webApp 'Microsoft.Web/sites@2024-04-01' = {
  name: webAppName
  location: location
  kind:'app,container,windows'
  properties: {
    serverFarmId: appServicePlan.id
    siteConfig: {
      windowsFxVersion: 'DOCKER|${dockerContainerImage}'
      appCommandLine: ''
      alwaysOn: true
      minTlsVersion: '1.3'
    }
    httpsOnly: true
  }
}

该模板定义两个 Azure 资源：

• Microsoft.Web/serverfarms：创建应用服务计划。
• Microsoft.Web/sites：创建应用服务应用。

该模板包含以下为方便起见预定义的参数：

部署模板

将模板复制并粘贴到首选编辑器或 IDE。 然后将该文件保存到本地工作目录。 使用 .bicep 文件扩展名。

在这里，使用 Azure CLI 部署模板。 还可以使用 Azure 门户、Azure PowerShell 或 REST API。 若要了解其他部署方法，请参阅 使用 Azure CLI 部署 Bicep 文件。

以下代码将创建一个资源组、一个应用服务计划和一个 Web 应用。 系统会为你设置默认资源组、应用服务计划和位置。 将 <app-name> 替换为一个全局唯一的应用名称。 有效字符是 a-z， 0-9和连字符（-）。

打开安装 Azure CLI 的终端。 运行此代码以创建 .NET 应用：

az group create --name myResourceGroup --location "southchinanorth2" &&
az deployment group create --resource-group myResourceGroup --template-file <path-to-template>