特定于仪表板的视觉对象

在 呈现运算符 的上下文中创建的所有可视化效果都可以在仪表板可视化效果中使用。 但是，以下可视化效果仅适用于 Azure 数据资源管理器 仪表板、Real-Time 仪表板或 Azure 数据资源管理器 Web UI，并且无法使用呈现运算符。

若要了解如何自定义任何仪表板视觉对象，请参阅“自定义Azure 数据资源管理器仪表板视觉对象。

有关Azure 数据资源管理器中仪表板的一般信息，请参阅 使用 Azure 数据资源管理器 仪表板对数据进行可视化。

Stat

你可以在 Azure 数据资源管理器 仪表板中使用 Stat。 它显示一个标量值。 从仪表盘的可视化选择器中选择它。

示例查询

StormEvents
| summarize TotalEvents = count()

选择 Stat 作为可视化类型。

多重统计

Multi Stat 在槽位网格中显示多个数值。 通过仪表板中的可视化选择器选择该可视化对象。

查询应返回标签列和值列。 你可以在可视化设置中明确选择 标签栏 和 价值栏 。

示例查询

datatable(Status:string, Count:long)
[
    "Active", 42,
    "Mitigated", 18,
    "Resolved", 73
]

在可视化设置中，选择第一个输出列为 标签列，第二个输出列为 价值列。

漏斗图

漏斗图可视化具有顺序连接的阶段的线性流程。 漏斗图的每个阶段代表总数的百分比。 因此，在大多数情况下，漏斗图的形状类似于一个漏斗，第一阶段为最大值，每个后一阶段的值都小于其前一阶段的值。

以下示例使用公开可用的ContosoSales中 数据库的数据，展示 2007 年加拿大洗衣机和烘干机的销量在销售总量中的数量。

示例查询

let interestingSales = SalesTable
| where DateKey between (datetime(2007) .. datetime(2008))
| join kind=inner Products on ProductKey;
let totalSales = interestingSales
| summarize sum(SalesAmount)
| extend Name="Total";
//totalSales
let homeAppliancesSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| summarize sum(SalesAmount)
| extend Name="Home Appliances";
//homeAppliancesSales
let washersAndDryersSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| where ProductSubcategoryName == "Washers & Dryers"
| summarize sum(SalesAmount)
| extend Name="Washers & Dryers";
//washersAndDryersSales
let canadaSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| where ProductSubcategoryName == "Washers & Dryers"
| where Country == "Canada"
| summarize sum(SalesAmount)
| extend Name="Canada";
//canadaSales
totalSales
| union homeAppliancesSales
| union washersAndDryersSales
| union canadaSales
| project Name, SalesAmount=sum_SalesAmount
| sort by SalesAmount desc

热图

热力图将感兴趣的主变量的值在两个轴变量下显示为彩色方块组成的网格。

要呈现热度地图，查询必须生成具有三列的表。 用于值字段的数据必须为数值。 将用于x和y值的列使用以下规则：

• 如果列x中的值采用string格式，列y中的值必须采用string格式。
• 如果列x中的值采用datetime格式，列y中的值必须为数值。

示例查询

StormEvents
| summarize count(EventId) by State, EventType