从查询引入（.set、.append、.set-or-append、.set-or-replace）

适用于：✅Azure 数据资源管理器

这些命令执行查询或管理命令，并将查询结果引入表中。 这些命令之间的区别在于它们如何处理现有的或不存在的表和数据。

若要从查询命令取消引入，请参阅 cancel operation。

权限

若要对表执行不同的操作，需要特定权限：

• 若要使用 .append 命令将行添加到现有表，至少需要表引入器权限。
• 若要使用各种 .set 命令创建新表，至少需要数据库用户权限。
• 若要使用 .set-or-replace 命令替换现有表中的行，至少需要表管理员权限。

有关权限的详细信息，请参阅 Kusto 基于角色的访问控制。

语法

(.set | .append | .set-or-append | .set-or-replace) [async] tableName [with (propertyName = propertyValue [, ...])] <| queryOrCommand

详细了解语法约定。

参数

性能提示

• 如果查询产生的数据量较大，超过 1 GB，且不需要序列化，则将 distributed 标志设置为 true。 然后，多个节点就可以并行产生输出。 如果查询结果较小，请不要使用此标志，因为可能会不必要地生成很多小数据分片。
• 数据引入是一项资源密集型操作，可能会影响数据库上的并发活动，包括正在运行的查询。 请避免同时运行过多的引入命令。
• 请将数据引入量限制为每个引入操作少于 1 GB。 如有必要，请使用多个引入命令。

支持的引入属性

架构注意事项

• .set-or-replace 会保留架构，除非 extend_schema 或 recreate_schema 引入属性之一已设置为 true。
• .set-or-append 和 .append 命令会保留架构，除非 extend_schema 引入属性已设置为 true。
• 将结果集架构与目标表的架构匹配是基于列类型进行的。 不对列名进行匹配。 确保查询结果架构列与表的顺序相同，否则数据会被引入到错误的列中。

字符限制

如果查询生成包含 $ 字符的实体名称，则命令会失败。 实体名称必须符合命名规则，因此必须删除 $ 字符，引入命令才能成功。

例如，在下面的查询中，search 运算符会生成列 $table。 若要存储查询结果，请使用 project-rename 重命名列。

.set Texas <| search State has 'Texas' | project-rename tableName=$table

示例

在数据库中创建名为 RecentErrors 的新表，该表与 LogsTable 具有相同的架构，并保存最近一小时的所有错误记录。

.set RecentErrors <|
   LogsTable
   | where Level == "Error" and Timestamp > now() - time(1h)

在数据库中创建一个名为“OldExtents”的新表，该表只有一列“ExtentId”，其中保存了数据库中超过 30 天前创建的所有盘区的盘区 ID。 数据库有一个名为“MyExtents”的现有表。 由于数据集预计大于 1 GB（超过约 100 万行），因此请使用 distributed 标志

.set async OldExtents with(distributed=true) <|
   MyExtents 
   | where CreatedOn < now() - time(30d)
   | project ExtentId

在当前数据库中将数据追加到名为“OldExtents”的现有表，该表包含单个列（即“ExtentId”），并保存数据库中已创建 30 天以上的所有盘区的盘区 ID。 基于名为“MyExtents”的现有表，用标记 tagA 和 tagB 来标记新盘区。

.append OldExtents with(tags='["TagA","TagB"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

在当前数据库中将数据追加到“OldExtents”表，或者创建该表（如果不存在）。 使用 ingest-by:myTag 标记新盘区。 只有在表尚未包含使用 ingest-by:myTag 标记的盘区的情况下，才应当基于名为“MyExtents”的现有表来进行标记。

.set-or-append async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <|
   MyExtents
   | where CreatedOn < now() - time(30d)
   | project ExtentId

在当前数据库中替换“OldExtents”表中的数据，或者创建该表（如果不存在）。 使用 ingest-by:myTag 标记新盘区。

.set-or-replace async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

将数据追加到当前数据库中的“OldExtents”表，同时将盘区创建时间设置为过去的某个特定日期/时间。

.append async OldExtents with(creationTime='2017-02-13T11:09:36.7992775Z') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId     

返回输出

返回通过 .set 或 .append 命令创建的盘区的信息。

示例输出