graph-to-table 运算符

适用于：✅Azure 数据资源管理器✅Azure Monitor✅Microsoft Sentinel

graph-to-table 运算符将图形中的节点或边导出到表。

语法

Nodes

G | graph-to-table nodes [ with_node_id=ColumnName ]

边缘

G | graph-to-table edges [ with_source_id=ColumnName ] [ with_target_id=ColumnName ] [ as TableName ]

节点和边

G | graph-to-table nodes as NodesTableName [ with_node_id=ColumnName ], edges as EdgesTableName [ with_source_id=ColumnName ] [ with_target_id=ColumnName ]

参数

返回

Nodes

graph-to-table 运算符返回表格结果，其中每一行对应于源图中的一个节点。 返回的列是节点的属性。 提供 with_node_id 时，节点哈希列的类型为 long。

边缘

graph-to-table 运算符返回表格结果，其中每一行对应于源图中的一个边。 返回的列是节点的属性。 提供 with_source_id 或 with_target_id 时，节点哈希列的类型为 long。

节点和边

graph-to-table 运算符返回两个表格结果，与前面的说明匹配。

示例

以下示例使用 make-graph 运算符从边和节点表生成图形。 节点表示人员和系统，边表示节点之间的不同关系。 然后，每个示例显示了 graph-to-table 的不同用法。

获取边

在此示例中，graph-to-table 运算符将图形中的边导出到表。 with_source_id 和 with_target_id 参数导出每个边的源节点和目标节点的节点哈希。

let nodes = datatable(name:string, type:string, age:long) 
[ 
	"Alice", "Person", 23,  
	"Bob", "Person", 31,  
	"Eve", "Person", 17,  
	"Mallory", "Person", 29,  
	"Trent", "System", 99 
]; 
let edges = datatable(source:string, destination:string, edge_type:string) 
[ 
	"Alice", "Bob", "communicatesWith",  
	"Alice", "Trent", "trusts",  
	"Bob", "Trent", "hasPermission",  
	"Eve", "Alice", "attacks",  
	"Mallory", "Alice", "attacks",  
	"Mallory", "Bob", "attacks"  
]; 
edges 
| make-graph source --> destination with nodes on name
| graph-to-table edges with_source_id=SourceId with_target_id=TargetId

输出

获取节点

在此示例中，graph-to-table 运算符将图形中的节点导出到表。 with_node_id 参数导出节点哈希。

let nodes = datatable(name:string, type:string, age:long) 
[ 
	"Alice", "Person", 23,  
	"Bob", "Person", 31,  
	"Eve", "Person", 17,
	"Trent", "System", 99
]; 
let edges = datatable(source:string, destination:string, edge_type:string) 
[ 
	"Alice", "Bob", "communicatesWith",  
	"Alice", "Trent", "trusts",  
	"Bob", "Trent", "hasPermission",  
	"Eve", "Alice", "attacks",  
	"Mallory", "Alice", "attacks",  
	"Mallory", "Bob", "attacks"
]; 
edges 
| make-graph source --> destination with nodes on name
| graph-to-table nodes with_node_id=NodeId

输出

获取节点和边

在此示例中，graph-to-table 运算符将图形中的节点和边导出到表。

let nodes = datatable(name:string, type:string, age:long) 
[ 
	"Alice", "Person", 23,  
	"Bob", "Person", 31,  
	"Eve", "Person", 17,
	"Trent", "System", 99
]; 
let edges = datatable(source:string, destination:string, edge_type:string) 
[ 
	"Alice", "Bob", "communicatesWith",  
	"Alice", "Trent", "trusts",  
	"Bob", "Trent", "hasPermission",  
	"Eve", "Alice", "attacks",  
	"Mallory", "Alice", "attacks",  
	"Mallory", "Bob", "attacks"
]; 
edges 
| make-graph source --> destination with nodes on name
| graph-to-table nodes as N with_node_id=NodeId, edges as E with_source_id=SourceId;
N; 
E

输出表 1

输出表 2

相关内容

• 图形运算符
• make-graph 运算符