快速入门：使用 Bicep 创建 Azure Synapse Analytics 专用 SQL 池（之前称为 SQL DW）

此 Bicep 文件将创建一个专用 SQL 池（之前称为 SQL DW），并启用了透明数据加密。 专用 SQL 池（之前称为 SQL DW）是指 Azure Synapse 中正式发布的企业数据仓库功能。

Bicep 是一种特定于域的语言 (DSL)，使用声明性语法来部署 Azure 资源。 它提供简明的语法、可靠的类型安全性以及对代码重用的支持。 Bicep 会针对你的 Azure 基础结构即代码解决方案提供最佳创作体验。

如果没有 Azure 订阅，可在开始前创建一个试用帐户。

本快速入门中使用的 Bicep 文件来自 Azure 快速入门模板。

@description('The SQL Logical Server name.')
param sqlServerName string = 'sql${uniqueString(resourceGroup().id)}'

@description('The administrator username of the SQL Server.')
param sqlAdministratorLogin string

@description('The administrator password of the SQL Server.')
@secure()
param sqlAdministratorPassword string

@description('The name of the Database.')
param databasesName string

@description('Enable/Disable Transparent Data Encryption')
@allowed([
  'Enabled'
  'Disabled'
])
param transparentDataEncryption string = 'Enabled'

@description('DW Performance Level expressed in DTU (i.e. 900 DTU = DW100c)')
@minValue(900)
@maxValue(54000)
param capacity int

@description('The SQL Database collation.')
param databaseCollation string = 'SQL_Latin1_General_CP1_CI_AS'

@description('Resource location')
param location string = resourceGroup().location

resource sqlServer 'Microsoft.Sql/servers@2021-11-01-preview' = {
  name: sqlServerName
  location: location
  properties: {
    administratorLogin: sqlAdministratorLogin
    administratorLoginPassword: sqlAdministratorPassword
    version: '12.0'
    publicNetworkAccess: 'Enabled'
    restrictOutboundNetworkAccess: 'Disabled'
  }
}

resource sqlServerDatabase 'Microsoft.Sql/servers/databases@2021-11-01-preview' = {
  parent: sqlServer
  name: databasesName
  location: location
  sku: {
    name: 'DataWarehouse'
    tier: 'DataWarehouse'
    capacity: capacity
  }
  properties: {
    collation: databaseCollation
    catalogCollation: databaseCollation
    readScale: 'Disabled'
    requestedBackupStorageRedundancy: 'Geo'
    isLedgerOn: false
  }
}

resource encryption 'Microsoft.Sql/servers/databases/transparentDataEncryption@2021-11-01-preview' = {
  parent: sqlServerDatabase
  name: 'current'
  properties: {
    state: transparentDataEncryption
  }
}

Bicep 文件定义了一个资源：

• Microsoft.Sql/servers

1. 将该 Bicep 文件在本地计算机上另存为 main.bicep。

2. 使用 Azure CLI 或 Azure PowerShell 来部署该 Bicep 文件。

   • CLI
   • PowerShell

   az group create --name exampleRG --location chinaeast2
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters sqlAdministratorLogin=<admin-login> databasesName=<db-name> capacity=<int>
   

   备注

   将 <admin-login> 替换为 SQL Server 的管理员登录用户名。 将 <db-name> 替换为数据库的名称。 将 <int> 替换为 DW 性能级别。 最小值为 900，最大值为 54000。 系统还会提示输入 sqlAdministratorPassword。

部署完成后，应会看到一条指出部署成功的消息。

使用 Azure 门户、Azure CLI 或 Azure PowerShell 列出资源组中已部署的资源。

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

如果不再需要资源组及其资源，请使用 Azure 门户、Azure CLI 或 Azure PowerShell 将其删除。

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

在本快速入门中，你使用 Bicep 创建了专用 SQL 池（之前称为 SQL DW），并验证了部署。 若要详细了解 Azure Synapse Analytics 和 Bicep，请参阅以下文章。

• 阅读 Azure Synapse Analytics 概述
• 详细了解 Bicep
• 快速入门：使用 Visual Studio Code 创建 Bicep 文件