快速入门：使用 Bicep 文件配置 NSG 流日志

在本快速指南中，您将学习如何使用 Bicep 文件启用 NSG 流日志。 有关详细信息，请参阅 NSG 流日志概述和什么是 Azure Resource Manager？

Bicep是一种特定于域的语言（DSL），它使用声明性语法来部署Azure资源。 它提供简明的语法、可靠的类型安全性以及对代码重用的支持。 Bicep为Azure中的基础结构即代码解决方案提供最佳创作体验。

先决条件

查看Bicep文件

本快速入门使用来自 Azure 快速入门模板 的 创建 NSG 流日志 的 Bicep 文件。

@description('Name of the Network Watcher attached to your subscription. Format: NetworkWatcher_<region_name>')
param networkWatcherName string = 'NetworkWatcher_${location}'

@description('Name of your Flow log resource')
param flowLogName string = 'FlowLog1'

@description('Region where you resources are located')
param location string = resourceGroup().location

@description('Resource ID of the target NSG')
param existingNSG string

@description('Retention period in days. Default is zero which stands for permanent retention. Can be any Integer from 0 to 365')
@minValue(0)
@maxValue(365)
param retentionDays int = 0

@description('FlowLogs Version. Correct values are 1 or 2 (default)')
@allowed([
  1
  2
])
param flowLogsVersion int = 2

@description('Storage Account type')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
])
param storageAccountType string = 'Standard_LRS'

var storageAccountName = 'flowlogs${uniqueString(resourceGroup().id)}'

resource storageAccount 'Microsoft.Storage/storageAccounts@2021-09-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: storageAccountType
  }
  kind: 'StorageV2'
  properties: {}
}

resource networkWatcher 'Microsoft.Network/networkWatchers@2022-01-01' = {
  name: networkWatcherName
  location: location
  properties: {}
}

resource flowLog 'Microsoft.Network/networkWatchers/flowLogs@2022-01-01' = {
  name: '${networkWatcherName}/${flowLogName}'
  location: location
  properties: {
    targetResourceId: existingNSG
    storageId: storageAccount.id
    enabled: true
    retentionPolicy: {
      days: retentionDays
      enabled: true
    }
    format: {
      type: 'JSON'
      version: flowLogsVersion
    }
  }
}

Bicep文件中定义了以下资源：

• Microsoft.Storage/storageAccounts
• Microsoft.Network 网络观察器
• Microsoft.Network 网络观察者/流日志

前面的示例中突出显示的代码显示了 NSG 流日志资源定义。

部署Bicep文件

本快速入门假设你有一个可以启用流日志记录的网络安全组。

验证部署

可通过两个选项来查看部署是否成功：

• 你的控制台显示 ProvisioningState 为 Succeeded。
• 转到 NSG 流日志门户页确认所做的更改。

如果部署出现问题，请参阅 使用 Azure Resource Manager 解决常见的 Azure 部署错误。

清理资源

可以使用完整的部署模式删除Azure资源。 若要删除流日志资源，请在完整模式下指定部署，而不包含要删除的资源。 详细了解完整部署模式。

还可以在Azure门户中禁用 NSG 流日志：

1. 登录到Azure门户。

2. 在门户顶部的搜索框中，输入网络监视工具。 从搜索结果中选择 Network Watcher。

3. 在“日志”下，选择“流日志”。

4. 在流日志列表中，选择要禁用的流日志。

5. 选择 “禁用”。

相关内容

在本快速入门中，您学习了如何使用 Bicep 文件启用 NSG 流日志。 接下来，了解如何使用流量分析可视化 NSG 流日志数据：

• 流量分析概述
• 流量分析使用方案
• 使用 Azure Policy 管理流量分析