地理空间可视化效果

适用于：✅Azure 数据资源管理器✅Azure Monitor✅Microsoft Sentinel

可以使用 呈现运算符将地理空间数据可视化为查询的一部分，点、馅饼或地图上 气泡。

有关地理空间聚类的详细信息，请参阅地理空间聚类。

可以使用 [经度, 纬度] 列或 GeoJSON 列将点可视化。 使用系列列是可选的。 [经度, 纬度] 对按该顺序定义每个点。

以下示例查找风暴事件并在地图上可视化 100 个点。

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

以下示例可视化多个点系列，其中 [经度, 纬度] 对定义每个点，第三列定义序列。 在此示例中，系列为 EventType。

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

以下示例在地图上可视化点系列。 如果结果中有多个列，则必须指定要用于 xcolumn（经度）、ycolumn（纬度）和系列的列。

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

以下示例使用 GeoJSON 动态值来可视化地图上的点，以定义点。

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

可以使用 [经度, 纬度] 列或 GeoJSON 列来可视化饼图或气泡图。 可以使用颜色或数值轴创建这些可视化效果。

以下示例显示了 S2 单元格聚合的 storm 事件。 图表按一种颜色的位置聚合气泡中的事件。

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

以下示例显示了 S2 单元格聚合的 storm 事件。 图表按位置按饼图中的事件类型聚合事件。

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

• 地理空间聚类分析
• Render 运算符
• 汽车测试车队的数据分析（地理空间聚类分析用例）
• 了解用于地理空间数据处理和分析的 Azure 体系结构